applications/euler/2d/Cyl/src/physbd2.f

!-----------------------------------------------------------------------
! Physical boundary conditions
! Interface:
!   mx,my    := shape of grid function
!
!   u(,) := grid function
!
!   lb(2) := lower bound for grid
!   ub(2) := upper bound for grid
!   lbbnd(2) := lower bound for boundary region
!   ubnd(2) := upper bound for boundary region
!   shapebnd(2) := shape of boundary region 
!   xc(2) := lower left corner of grid
!   dx(2) := grid spacing
!   dir := at which side of the grid is the boundary?
!   bnd(,2,2) := lower left and upper right corner of global grid and 
!      of mb-1 internal boundary regions 
!-----------------------------------------------------------------------

      subroutine physbd(u,mx,my,lb,ub,lbbnd,ubbnd,shapebnd,
     &     xc,dx,dir,bnd,mb,time,args,argc)

      implicit double precision (a-h,o-z)
      include  "cuser.i"

      integer   argc, args, mx, my, mb, dir
      integer   lb(2), ub(2), lbbnd(2), ubbnd(2), shapebnd(2)
      real*8    u(args, mx, my), xc(2), dx(2), bnd(mb,2,2), time

!      Local variables
      integer   i, j, imin, imax, jmin, jmax, jsym
      integer   stride, stridebnd, meqn, getindx
      integer   isx(4), isy(4)
c
      data isx /1,-1,1,1/
      data isy /1,1,-1,1/

      hxmarg = hx*.01
      hymarg = hy*.01

      meqn = args

!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!      See definition of member-function extents() in BBox.h 
!      for calculation of stride
         
      stride = (ub(1) - lb(1))/(mx-1)
      
      if (meqn .ne. 4) then
         write(0,*)'ERROR in physbd: '
      else

!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!     Find working domain
         
         imin = getindx(max(lbbnd(1), lb(1)), lb(1), stride)
         imax = getindx(min(ubbnd(1), ub(1)), lb(1), stride)
         
         jmin = getindx(max(lbbnd(2), lb(2)), lb(2), stride)
         jmax = getindx(min(ubbnd(2), ub(2)), lb(2), stride)
         
         if(imax .gt. mx .or. jmax .gt. my .or. 
     &        imin .lt. 1 .or. jmin .lt. 1) then
            write(0,*)'INDEX ERROR in physbd'
         end if

!        Left Side --- Reflecting
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
         if (dir.eq.0) then
            do 200 i = imax, imin, -1
               iref = 2*imax+1-i
               do 200 j = jmin, jmax
                  do 200 m = 1, meqn
                     u(m,i,j) = u(m,iref,j)*isx(m)
 200        continue
            return
         end if

!        Right Side --- extrapolate
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
         if (dir.eq.1) then
            do 210 i = imin, imax
               do 210 j = jmin, jmax
                  do 210 m = 1, meqn
                     u(m,i,j) = u(m,i-1,j)
 210        continue
            return
         end if
         
!        Bottom Side --- Reflecting
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
         if (dir.eq.2) then
            do 220 j = jmax, jmin, -1
               jref = 2*jmax+1-j
               do 220 i = imin, imax
                  do 220 m = 1, meqn
                     u(m,i,j) = u(m,i,jref)*isy(m)
 220        continue
            return
         end if

!        Top Side --- Reflecting
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
         if (dir.eq.3) then
            do 230 j = jmin, jmax
               do 230 i = imin, imax
                  do 230 m = 1, meqn
                     u(m,i,j) = u(m,i,j-1)*isy(m)
 230        continue
            return
         end if
      end if
      
      return
      end